STEEL HEAD THERMISTOR

Description

  • Wide temperature range: 125 to -25 Celsius
  • Long cable with terminal
  • Waterproof, suitable for immersive temperature detection
  • Steelhead
  • Easy to use and set up

Perfect thermistor for slow-cooking projects, for dehydrating, or for anything else within inside its wide temperature range. It’s easy to set up and you only need a resistor (included) to get it working with the Arduino-compatible board.

Temperature range -25 ºC to 125 ºC
Resistance 10k Ohm at 25 ºC
B coeficient 3950 (25 ºC / 50 ºC)
Weight 7 g

To read the temperature of the thermistor, set it up as a voltage divider. Connect one end of the thermistor to ground, the other end out into Analog in and into a 10k resistor connected to 5volts.

Supply voltage to the thermistor connecting the GND pin to one of the thermistor outputs with a male to male jumper cable. Connect the other output to the breadboard with a male to male jumper cable. On the same column connect one end of the 10k resistor and another male to male jumper cable going to your Analog in (in our example, A0). The other end of the resistor goes to 5 volts, connecting another male to male jumper cable from this column of the breadboard to 5V on your Arduino-compatible board.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
/*Rewieved by Dr. Mangus for MangoLabs
      Thermistor example */
// which analog pin to connect
#define THERMISTORPIN A0        
// resistance at 25 degrees C
#define THERMISTORNOMINAL 10000     
// temp. for nominal resistance (almost always 25 C)
#define TEMPERATURENOMINAL 25  
// how many samples to take and average, more takes longer
// but is more 'smooth'
#define NUMSAMPLES 20
// The beta coefficient of the thermistor (usually 3000-4000)
#define BCOEFFICIENT 3950
// the value of the 'other' resistor
#define SERIESRESISTOR 10050  
  
int samples[NUMSAMPLES];
  
void setup(void) {
  Serial.begin(9600);
}
  
void loop(void) {
  uint8_t i;
  float average;
  
  // take N samples in a row, with a slight delay
  for (i=0; i< NUMSAMPLES; i++) {
   samples[i] = analogRead(THERMISTORPIN);
   delay(10);
  }
  
  // average all the samples out
  average = 0;
  for (i=0; i< NUMSAMPLES; i++) {
     average += samples[i];
  }
  average /= NUMSAMPLES;
  
  Serial.print("Average analog reading ");
  Serial.println(average);
  
  // convert the value to resistance
  average = 1023 / average - 1;
  average = SERIESRESISTOR / average;
  Serial.print("Thermistor resistance ");
  Serial.println(average);
  
  float steinhart;
  steinhart = average / THERMISTORNOMINAL;     // (R/Ro)
  steinhart = log(steinhart);                  // ln(R/Ro)
  steinhart /= BCOEFFICIENT;                   // 1/B * ln(R/Ro)
  steinhart += 1.0 / (TEMPERATURENOMINAL + 273.15); // + (1/To)
  steinhart = 1.0 / steinhart;                 // Invert
  steinhart -= 273.15;                         // convert to C
  
  Serial.print("Temperature ");
  Serial.print(steinhart);
  Serial.println(" *C");
  
  delay(1000);
}
  1. In this example we are connecting:
    Arduino    Thermistor
    GND    —  OUT1
    A0     —  OUT2
    A0     —  10k resistor
    5V  —  10k resistor (the other end)
  2. Download and install the Arduino environment from here or use the web editor.
  3. Download the sketch here and open, or open the Arduino environment and copy the code into a blank sketch.
  4. Connect your board to your computer with the included USB cable.
  5. Select your board in Tools / Board / Arduino Uno.
  6. Select your port in Tools / Port / COM# (Arduino Uno). This may be slightly different depending on your operating system.
  7. Upload by pressing the arrow in the circle to the upper left.
  8. To open the serial monitor, press the magnifying glass icon on the upper right.
  9. Set the baud rate to 9600 on the lower right.
  10. Touch the thermistor to check whether the temperature displayed on the serial monitor changes.That’s it!